''' Aantal subcirkels : 3, of data aanpassen
DEFDBL A-Z
k = 3
DIM r(k), alf(k), thet(k)
FOR m = 1 TO k: READ r(m): NEXT m
FOR m = 1 TO k: READ alf(m): NEXT m
FOR m = 1 TO k: READ thet(m): NEXT m
pi = ATN(1) * 4
x0 = 320: y0 = 240
SCREEN 12
LOCATE 3, 1: COLOR 11
PRINT "   PlaneetVul: Baan van satelliet van planeet van ster."
LOCATE 7, 1: COLOR 7
PRINT "   MetaBaan van beschrijvend punt op die baan."
PRINT "   Attractorachtige baanvulling naargelang"
PRINT "   hoekincrement van beschrijvend punt. "
PRINT "   De satellietbaan is zelf niet periodiek (niet gesloten:"
PRINT "   te zien met kleine hoekincrementen)"
PRINT "   Sommige metabanen (met grote hoeken) blijken dat wel te zijn"
PRINT
PRINT "-> Probeer kleine en grote hoeken, ook veelvouden van"
PRINT "   90 en 360 graden, en kleine afwijkers bv 720 en 721, 3600 en 3600.1 ..."
PRINT "-> Druk toets om te onderbreken, en weer om nieuwe hoek te geven."
PLAY "l21o3c+ef+g+>c<g+f+e-c"
COLOR 14: LOCATE 24, 17: PRINT "Credits: guido wuyts 1995"
col = 11: a$ = ""
WHILE a$ = ""
COLOR col: LOCATE 27, 18
PRINT "-> Druk een toets..."
tijd = TIMER: WHILE TIMER - tijd < .5: WEND
IF col = 11 THEN col = 5 ELSE col = 11
a$ = INKEY$
WEND
a$ = "": CLS

weer:
LOCATE 1, 1
COLOR 11
INPUT "-> Hoekincrement (0=END) ? ", t
IF t = 0 THEN END
PRINT : PRINT
COLOR 7
PRINT "   (Typ '-' om baanpunten te verbinden)"
COLOR 11
LOCATE CSRLIN - 2, 1
INPUT "-> Punten verbinden ? ", p$
'SCREEN 12
CLS
COLOR 3: PRINT t
t = pi * t / 180
CIRCLE (x0, y0), 4, 14
SLEEP 1
x = x0: y = y0                  '''eerste punt...
RESTORE leesthet
FOR m = 1 TO k: READ thet(m): NEXT m
FOR j = 1 TO k
thet(j) = thet(j) + alf(j) * t
x = x + r(j) * COS(thet(j)) * 2
y = y + r(j) * SIN(thet(j)) * 2
NEXT j
PSET (x, y)                  '''...eerste punt

DO
x = x0: y = y0
FOR j = 1 TO k
thet(j) = thet(j) + alf(j) * t
x = x + r(j) * COS(thet(j)) * 2
y = y + r(j) * SIN(thet(j)) * 2
NEXT j
IF p$ = "-" THEN LINE -(x, y), 3 ELSE PSET (x, y), 11
a$ = INKEY$
LOOP WHILE a$ = ""
PLAY "o4l12d"
a$ = INPUT$(1)
GOTO weer

lees:
DATA 60,45.5 ,10.23   : 'stralen hoofd- en subcirkels
                        'rayons cercle et souscercles
DATA .5 ,3.123 ,10.23 : 'rel. hoektoename
                        'augment. angul. relat.
leesthet:
DATA 1.0,0.0,2.0,0.   : 'beginhoeken
                        'angles de depart

END